Stata: Kaplan-Meier曲線を作成する

StataでKaplan-Meier曲線を描いてみましょう。

変数outcomeとoutcome_dayは下記の通り定義されています。

  • outcome: 0=アウトカム発症無し、1=有り
  • outcome_day: アウトカム発症までの追跡期間(日)

Kaplan-Meier曲線を描く

outcomeとoutcome_dayを用いて、とりあえずKaplan-Meier曲線を描いてみましょう。

stset outcome_day, failure(outcome==1)

sts graph

このKaplan-Meier曲線に設定を追加して、下図を作成します。

この図を作成するためには、以下の魔法を唱える必要があります。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small)) risktable(0 730.5 1461 2191.5 2922 3652.5, size(small) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") rowtitle(, justification(left)) title(, size(small))) graphregion(color(white) lcolor(white))

それでは、この魔法が作られた過程を、ひとつひとつ順番に確認していきましょう。

グラフのサイズを変更する

グラフのサイズを変更します。デフォルトは4.0 × 5.5インチです。

A4サイズ(8.27 x 11.69インチ)に2 x 3個のグラフを収まるサイズにしたいので、図のサイズを3.7 x 3.7 インチに設定します。

sts graph, xsize(3.7) ysize(3.7)

 

グループ別のKM曲線を描く

飲酒頻度別にKaplan-Meier曲線を描きます。変数drinkingは下記の通り定義されています。

  • drinking = 1(週0日)
  • drinking = 2(週1-3日)
  • drinking = 3(週4-6日)
  • drinking = 4(週7日)

sts graph, xsize(3.7) ysize(3.7) by(drinking)

 

故障率を描く、Y軸の範囲を設定する

グラフ下部の空欄がもったいないので、0.00から増加してくる故障率を描きます。y軸は0.0〜0.6の範囲で0.2ずつ刻みます。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6)

 

Y軸ラベルを水平に配置する

Y軸ラベルが垂直になっていますので、水平に配置します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0))

 

Y軸ラベルの文字サイズを小さくする

Y軸ラベルが少し大きいので、文字サイズを小さくします。Stataでは文字サイズを下記の順番で設定しています。

  • tiny
  • vsmall
  • small
  • medsmall
  • medium
  • medlarge
  • large
  • vlarge
  • huge

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small))

 

Y軸ラベルの桁数を調整する

Y軸ラベルの小数点以下の桁数を2桁から1桁に変更します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f))

 

Y軸のグリッド線を削除する

Y軸グリッド線を削除して、グラフをスッキリさせましょう。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid)

 

 

Y軸に目盛り線を追加する

Y軸に0.1毎の目盛り線(tick)を追加します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6)

 

X軸ラベルを変更する

X軸のラベルを0〜10年の範囲で2年毎に表示します。また、フォントサイズをsmallに設定し、目盛り線(tick)を1年毎に追加します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5)

 

軸タイトルを追加・変更する

X軸タイトルに”Observational period (year)”を、Y軸タイトルに”Cumulative probability of incidence of hypertension”を追加します。文字サイズはsmallを設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle("Observational period (year)", size(small)) ytitle("Cumulative probability of incidence of hypertension", size(small))

ちょっと軸に近すぎるので、軸タイトルと軸の間にスペースを追加して、軸タイトルと軸の間隔を調整しましょう。また、Y軸を2行に分割します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small))

 

タイトルを挿入する

タイトル”Drinking frequency and incidence of hypertension”を挿入します。文字サイズをmedsmallに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall"))

 

タイトルを左上に配置する

タイトルをグラフ全域の左上(11時方向)に配置する

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11))

 

凡例をグラフ内部に表示する

凡例(legend)をプロット領域内部に表示します。legendと軸線からの距離を設定するlegendのringオプションを0に設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0))

 

凡例を左上に表示する

凡例をプロットエリアの左上(11時方向)に表示します。legendのpositionオプションを11に設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11))

 

凡例を縦長に表示する

凡例を縦長に1列で表示します。legendのcolsオプションを1に設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1))

 

凡例の枠線を表示しない

凡例の枠線の色を白に設定して、枠線を消します。legendのregionオプションを利用します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)))

なんとなくそれっぽい図になってきました。

 

凡例のラベルを変更する

凡例のラベルを下記の通りに変更します。

  • drinking = 1 を 0 day/week
  • drinking = 2 を 1-3
  • drinking = 3 を 4-6
  • drinking = 4 を 7

legendのorderオプションを利用します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(1 "0 day/week" 2 "1-3" 3 "4-6" 4 "7"))

 

凡例の順番を変更する

生存曲線と凡例の上下の順番が逆になっているので、凡例の順番を変更します。legendのorderオプション内の順番を変更します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0"))

 

凡例にタイトルを挿入する

凡例にタイトル”Drinking frequency”を挿入します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") title("Drinking frequency"))

 

凡例のタイトル、ラベルの文字サイズを小さくする

凡例ラベルとタイトルの文字が大きいので、いずれもsmallに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small")))

 

生存曲線のパターンを変更する

drinking=1, 2, 3, 4の生存曲線のパターンを下記の通りに設定します。

  • drinking = 1 に solid
  • drinking = 2 に dash
  • drinking = 3 に dash_dot
  • drinking = 4 に shortdash

4種類の生存曲線に対して、plot1opt、plot2opt、plot3opt、plot4optのオプションを利用してそれぞれに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash))

 

生存曲線の色を変更する

生存曲線の色をまとめて黒に設定します。plotoptのlcolorオプションで4本まとめて設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black))

 

P値を挿入する

P<0.001をポイント(x=3650, y=0)の上方左側(northwest)に挿入します。文字サイズをsmallに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small))

 

かなりそれっぽくなってきました。

 

リスク表を追加する

0, 2, 4, 6, 8, 10年時に追跡中の対象数を表示します。risktableオプションで表示する時間を指定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small)) risktable(0 730.5 1461 2191.5 2922 3652.5)

 

 

リスク表のラベル順番を変更する

リスクテーブルの順番を逆にして、ラベルを変更します。凡例と同様に、orderオプションを利用します。また、文字サイズをsmallに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small)) risktable(0 730.5 1461 2191.5 2922 3652.5, size(small) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0"))

 

リスク表のラベルを左揃えに設定する

凡例と同様に、リスク表のラベルを左揃えに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small)) risktable(0 730.5 1461 2191.5 2922 3652.5, size(small) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") rowtitle(, justification(left)))

 

リスク表のタイトルを小文字に設定する

リスク表のNumber at riskだけ文字が大きいので、smallに設定します。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small)) risktable(0 730.5 1461 2191.5 2922 3652.5, size(small) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") rowtitle(, justification(left)) title(, size(small)))

 

背景を無地白色に設定する

背景色および境界線を白色に設定して、ようやく完成です。

sts graph, xsize(3.7) ysize(3.7) by(drinking) failure ylabel(0.0(0.2)0.6, angle(0) labsize(small) format(%9.1f) nogrid) ytick(0.0(0.1)0.6) xlabel(0 "0" 730.5 "2" 1461 "4" 2191.5 "6" 2922 "8" 3652.5 "10", labsize(small)) xtick(0(365.25)3652.5) xtitle(" " "Observational period (year)", size(small)) ytitle("Cumulative probability of" "incidence of hypertension" " ", size(small)) title("A. Drinking frequency and incidence of hypertension" " ", size("medsmall") span position(11)) legend(ring(0) position(11) cols(1) region(lcolor(white)) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") size(small) title("Drinking frequency", size("small"))) plot1opt(lpattern(solid)) plot2opt(lpattern(dash)) plot3opt(lpattern(dash_dot)) plot4opt(lpattern(shortdash)) plotopt(lcolor(black)) text(0 3650 "P<0.001", place(nw) size(small)) risktable(0 730.5 1461 2191.5 2922 3652.5, size(small) order(4 "7 days/week" 3 "4-6" 2 "1-3" 1 "0") rowtitle(, justification(left)) title(, size(small))) graphregion(color(white) lcolor(white))

これであなたも美しいKaplan-Meier曲線を作成する魔法を手に入れました。いろんなところで使ってみて下さい。

 

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

このサイトはスパムを低減するために Akismet を使っています。コメントデータの処理方法の詳細はこちらをご覧ください